Mythruna

/**
 *  In the previous "player-hook-example" script, we learned
 *  how to hook scripts to the playerJoined event.  In this script,
 *  we'll be extending that to add a new build-mode tool to the player.
 *
 *  To make it more interesting, I will be adding two tools to a
 *  tool group.  So when the general tool category is selected then
 *  ctrl + mouse wheel will switch between them.
 */

// This script will access entity data and so need to import
// that packages that contains those components
import mythruna.es.*;
import mythruna.script.*;
 

/**
 *  This is a simple action that dumps some information about a
 *  clicked on block.
 */ 
action( group:"Example Tools", name:"Block Info", type:ActionType.Block ) {

    def loc = it.getBlock();    
    type = world.getType( loc.x, loc.y, loc.z, null );

    console.echo( "Block type:" + type + "  at:" + loc ); 
}

/**
 *  Dumps some information about an object that is clicked.
 */ 
action( group:"Example Tools", name:"Object Info", type:ActionType.Object ) {

    console.echo( "Object:" + it.object + " at:" + it.location );
    
    // The 'object' in this case is an entity.
    //
    // In Mythruna, all objects are entities and are part of the 'entity 
    // system'.  This includes players, blueprints, placeable objects, etc..
    // You can find many confusing and enlightening articles on 'Entity Systems' 
    // online.  They are a flexible and scalable way of supporting these
    // kinds of games.  The deeper topic is too much for this example but
    // the Mythruna-script API provides convenient access to entity data.
    //
    // An entity can have various types of data components associated 
    // with it.  Here we will access some data components of the clicked
    // placeable object.
    //
    // The raw entity system is available as the 'entities' reference.
    // So you can manually use:
    // entities.getComponent( someEntity, SomeComponent.class )
    // or you can more simlpy use:
    // someEntity[SomeComponent.class]
    //
    // Likewise, you can set data by directly calling:
    // entities.setComponent( someEntity, new Name("My Name") )
    // or you can use the shortcut:
    // someEntity << new Name("My Name") 
    //
    // Some data components like name are common enough that a more
    // convenient access was provided:
    // someEntity.name
    // ...will return someEntity[Name.class].name if the name component
    // is not null or null if it is.
    //
    // Let's dump some information about the clicked object now:
    
    def entity = it.object;
    console.echo( "Position:" + entity[Position.class] );
    console.echo( "Name:" + entity[Name.class] );
    console.echo( "Blueprint info:" + entity[ModelInfo.class] );
    console.echo( "Created by:" + entity[CreatedBy.class] );
    
    // We can go one further and get the name of the creator if it
    // has one
    if( entity[CreatedBy.class] != null )
        console.echo( "   " + entity[CreatedBy.class].creatorId.name );
}
 
 
  
on( [playerJoined] ) {
    type, event ->
    
    // When a player entity is created, certain tool actions are
    // added to them.  The tool group controls which mouse-wheel tool
    // they fall under and the name controls the ctrl + mouse-wheel
    // tool.  Right now, user defined tools only work with left-click.
    
    def refs = []

    // Get the existing tools that might be on the player since we
    // don't want to blow them away.
    ToolActions existing = player[ToolActions.class];
 
    // Note: 'player' in this case is an entity just like any other
    //       and may have similar data components to what was described
    //       above in the object info action.
 
    refs += actions.getRef( "Example Tools", "Block Info" );
    refs += actions.getRef( "Example Tools", "Object Info" );
    
    player << new ToolActions(refs, existing)     
}

mythruna.es.*
mythruna.script.*

mythruna.script.ActionType
mythruna.script.ToolActions